Giới thiệu
ESP8266 cung cấp khả năng kết nối mạng wifi đầy đủ và khép kín, bạn có thể sử dụng nó để tạo một web server đơn giản hoặc sử dụng như một access point.
Bài viết tổ hợp nhiều kiến thức về:
- Lập trình C/C++.
- Kiến trúc phần mềm.
- Lập trình Arduino.
- Lập trình web.
- Mạng máy tính, giao thức HTTP.
- Thao tác với tập lệnh AT.
Thông số kỹ thuật
- Wifi 802.11 b/g/n
- Wifi 2.4 GHz, hỗ trợ WPA/WPA2
- Chuẩn điện áp hoạt động 3.3v
- Chuẩn giao tiếp nối tiếp UART với tốc độ Baud lên đến 115200
- Có 3 chế độ hoạt động: Client, Access Point, Both Client and Access Point
- Hỗ trợ các chuẩn bảo mật như: OPEN, WEP, WPA_PSK, WPA2_PSK, WPA_WPA2_PSK
- Hỗ trợ cả 2 giao tiếp TCP và UDP
- Tích hợp công suất thấp 32-bit CPU có thể được sử dụng như là bộ vi xử lý ứng dụng
- SDIO 1.1 / 2.0, SPI, UART
- Làm việc như các máy chủ có thể kết nối với 5 máy trạm.
Sơ đồ chân và các chức năng
- URXD (RX): dùng để nhận tín hiệu trong giao tiếp UART với vi điều khiển
- VCC: đầu vào 3.3v
- GPIO 0: kéo xuống thấp cho chế độ upload bootloader
- RST: chân reset cứng của module, kéo xuống mass để reset
- GPIO 2: thường được dùng như một cổng TX trong giao tiếp UART để debug lỗi
- CH_PD: kích hoạt chip, sử dụng cho Flash Boot và updating lại module, nối với mức cao
- GND: nối với mass
- UTXD (TX): dùng để truyền tín hiệu trong giao tiếp UART với vi điều khiển
Sơ đồ lắp đặt mạch Arduino giao tiếp với ESP8266 điều khiển bật tắt LED thông qua wifi
Ở đây tôi sử dụng trực tiếp LED nối với chân D13 được tích hợp sẵn trên board Arduino.
Môi trường thử nghiệm
- Trình duyệt web Mozilla Firefox 48.0.1
- Window 10 Pro
- Arduino IDE 1.6.4
- Module wifi ESP8266 v1
- Board Arduino Uno
Đối với các môi trường phần cứng khác bạn vui lòng tự điều chỉnh cho phù hợp.
Những điểm cần lưu ý khi nạp code cho Arduino Uno để giao tiếp với ESP8266
Arduino Uno nạp code bằng bootloader sử dụng USB UART. Arduino Uno gửi lệnh điều khiển (tập lệnh AT) cho ESP8266 cũng bằng giao tiếp UART. Tuy nhiên board Arduino chỉ có 1 chân RX và 1 chân TX cho phép thực hiện giao tiếp UART. Điều đó dẫn đến 2 sự lựa chọn:
- Sử dụng chân RX và TX có sẵn trên Arduino để nạp code sau khi nạp code xong thì mới kết nối 2 chân đó với ESP8266. Với phương pháp này bạn phải thêm một khoảng thời gian delay ở hàm setup() để đảm bảo là sau khi kết nối ESP8266 với Arduino, thì ESP8266 vẫn nhận được đầy đủ các tập lệnh AT từ Arduino. Tuy nhiên, bạn không thể debug qua cổng Serial do cổng này đang đóng vai trò kết nối với ESP8266.
- Sử dụng SoftwareSerial để giả lập thêm 1 cổng Serial nữa để gửi tập lệnh AT cho ESP8266. Thư viện SoftwareSerial đã được trang bị sẵn trong Arduino IDE nên bạn không cần phải tải thêm. Với cách này thì bạn có thể debug thông qua Serial tuy nhiên code sẽ phức tạp hơn.
Ở ví dụ dưới đây tôi chọn phương án thứ nhất và chọn thời gian delay là 5s để kết nối chân TX và RX của Arduino với chân RX và TX của ESP8266 ngay sau khi nạp code thành công.
Code ESP8266 làm web server gửi lệnh bật tắt LED 13
Bạn có thể download code mẫu tại đây hoặc sao chép từ bên dưới (khuyến khích tải thay vì sao chép để tránh các vấn đề về Unicode).
#define LED_PIN 13
#define CMD_SEND_BEGIN "AT+CIPSEND=0"
#define CMD_SEND_END "AT+CIPCLOSE=0"
#define STDIO_PROTOCOL_HTTP 80
#define STDIO_PROTOCOL_HTTPS 443
#define STDIO_PROTOCOL_FTP 21
#define STDIO_PROTOCOL_CURRENT STDIO_PROTOCOL_HTTP
#define STDIO_CHAR_CR 0x0D
#define STDIO_CHAR_LF 0x0A
#define STDIO_STRING_EMPTY ""
#define STDIO_DELAY_SEED 1000
#define STDIO_DELAY_1X (1*STDIO_DELAY_SEED)
#define STDIO_DELAY_2X (2*STDIO_DELAY_SEED)
#define STDIO_DELAY_3X (3*STDIO_DELAY_SEED)
#define STDIO_DELAY_4X (4*STDIO_DELAY_SEED)
#define STDIO_DELAY_5X (5*STDIO_DELAY_SEED)
bool hasRequest = false;
void setup()
{
delay(STDIO_DELAY_5X);
Serial.begin(115200);
pinMode(LED_PIN, OUTPUT);
digitalWrite(LED_PIN, LOW);
initESP8266();
}
void loop()
{
while(Serial.available())
{
bufferingRequest(Serial.read());
}
if(hasRequest == true)
{
String htmlResponse = "<!doctype html>"
"<html>"
"<head>"
"<title>STDIO.VN ESP8266 DEMO</title>"
"</head>"
"<body>"
"<h1>STDIO.VN ESP8266 DEMO</h1>"
"<form action='' method='GET'>"
"<input type='radio' name='LED' name='STDIO' value='STDIO_ON' /> LED ON<br/>"
"<input type='radio' name='LED' name='STDIO' value='STDIO_OFF' /> LED OFF<br/>"
"<input type='submit' value='Submit' />"
"</form>"
"</body>"
"</html>";
String beginSendCmd = String(CMD_SEND_BEGIN) + "," + htmlResponse.length();
deliverMessage(beginSendCmd, STDIO_DELAY_1X);
deliverMessage(htmlResponse, STDIO_DELAY_1X);
deliverMessage(CMD_SEND_END, STDIO_DELAY_1X);
hasRequest = false;
}
}
void initESP8266()
{
deliverMessage("AT+RST", STDIO_DELAY_2X);
deliverMessage("AT+CWMODE=2", STDIO_DELAY_3X);
deliverMessage("AT+CWSAP=\"STDIO_ESP8266\",\"STDIOElectronics\",1,4", STDIO_DELAY_3X);
deliverMessage("AT+CIFSR", STDIO_DELAY_1X);
deliverMessage("AT+CIPMUX=1", STDIO_DELAY_1X);
deliverMessage(String("AT+CIPSERVER=1,") + STDIO_PROTOCOL_CURRENT, STDIO_DELAY_1X);
}
void bufferingRequest(char c)
{
static String bufferData = STDIO_STRING_EMPTY;
switch (c)
{
case STDIO_CHAR_CR:
break;
case STDIO_CHAR_LF:
{
STDIOProcedure(bufferData);
bufferData = STDIO_STRING_EMPTY;
}
break;
default:
bufferData += c;
}
}
void STDIOProcedure(const String& command)
{
hasRequest = command.startsWith("+IPD,");
if(command.indexOf("STDIO_OFF") != -1)
{
digitalWrite(LED_PIN, LOW);
}
else if(command.indexOf("STDIO_ON") != -1)
{
digitalWrite(LED_PIN, HIGH);
}
}
void deliverMessage(const String& msg, int dt)
{
Serial.println(msg);
delay(dt);
}Chạy thử nghiệm
Lần lượt thực hiện các bước sau để kiểm tra việc điều khiển bật tắt LED 13 thông qua wifi với module ESP8266
- Kết nối đến thiết bị và kiểm tra tín hiệu
- Truy cập vào địa chỉ IP của module wifi ESP8266 (mặc định là 192.168.4.1) và kiểm tra tính năng
Kết nối đến module wifi ESP8266 v1
Mở command prompt (Start > Run gõ cmd) và gõ lệnh sau để kiểm tra tín hiệu kết nối.
ping 192.168.4.1Nếu kết nối thành công bạn sẽ nhận được kết quả sau:
Truy cập vào IP của module wifi ESP8266 (mặc định là 192.168.4.1) và kiểm tra tính năng
Trong trường hợp này tôi dùng trình duyệt web Google Chrome 50+ để kiểm tra.
